CFAPPLICATION |
Description Defines the scope of a ColdFusion application; enables and disables storage of Client variables; specifies the Client variable storage mechanism; enables Session variables; and sets Application variable timeouts.
Category Application framework tags
Syntax
    <cfapplication
       name = "application_name"
       loginStorage = "cookie" or "session"
       clientManagement = "yes" or "no"
       clientStorage = "datasource_name" or "Registry" or "Cookie"
       setClientCookies = "yes" or "no"
       sessionManagement = "yes" or "no"
       sessionTimeout = #CreateTimeSpan(days, hours, minutes, seconds)#
       applicationTimeout = #CreateTimeSpan(days, hours, minutes, seconds)#
       setDomainCookies = "yes" or "no"
       scriptProtect = "none", "all", or list>
See also cfassociate, cferror, cflock, cfmodule; Chapter 5, "Application.CFC Reference," on page 1201; Chapter 13, "Designing and Optimizing a ColdFusion Application" and Chapter 37, "Integrating J2EE and Java Elements in CFML Applications," in ColdFusion MX Developer's Guide
History ColdFusion MX 7: Added scriptProtect attribute ColdFusion MX 6.1: Added loginStorage attribute ColdFusion MX: Changed how persistent scopes are available: Server, Session, and Application scope variables are stored in memory as structures. In earlier releases, only Session and Application scope variables were stored this way. You cannot access the UDF function scope as a structure. Changed the algorithm for setting the CFTOKEN variable value: if the registry key UUIDToken is a non-zero value, ColdFusion uses a number constructed from the UUID plus a random number. Otherwise, ColdFusion sets the CFTOKEN variable default value using a positive random integer. (In earlier releases, ColdFusion always used a number constructed from the UUID plus a random number.)
Usage This tag is typically used in the Application.cfm file, to set defaults for a ColdFusion application.
Note: | You can also set the application defaults in the Application.cfc file. For more information, see "Application variables" on page 1201.
This tag enables application variables, unless they are disabled in the ColdFusion Administrator. The Administrator setting also overrides the sessionManagement attribute. For more information, see Configuring and Administering ColdFusion MX. If ColdFusion is running on a cluster, you must specify clientStorage = "cookie" or a data source name; you cannot specify "registry". ColdFusion generates an error if the application name is longer than 64 characters. The CFTOKEN variable is 8 bytes in length. Its range is 10000000 -99999999.
Note: | If you specify ClientStorage=cookie, any Client scope variables set following a cfflush tag are not saved in the Client browser.
Protecting variables from cross-site scripting attacks The ScriptProtect attribute lets you protect one or more variable scopes from cross-site scripting attacks, where a client attempts to get your application to send malicious code back to a user's browser. In these attacks, user input (for example, from form fields or from URL variables) sets a CF variable which is destined for user output. The submitted data includes malicious code, such as JavaScript or an applet or object reference, which then executes on the user's system.
Note: | The ColdFusion MX Administrator Settings page Enable Global Script Protection option determines the default script protection setting. You can use the scriptProtect attribute to override the Administrator setting. You can also use the Application.cfc initialization code to set the protection value.
The ColdFusion MX cross-site scripting protection operation is done when ColdFusion MX processes the application settings at the beginning of a request. Thus, it can process the URL, and Cookie, CGI, and Form variables in a user's request. By default, it replaces occurrences of the following tag names with the text InvalidTag: object, embed, script, applet, and meta. It allows these names in plain text, replaces the words if they are used as tag names. You can specify any or all ColdFusion scopes for protection, but only the Form, URL, CGI, and Cookie scopes have variables that are often provided by unknown sources. Also, protecting a scope requires additional processing. For these reasons, the all attribute value applies protection to only the four scopes. The script protection mechanism applies a regular expression that is defined in the cf_root/lib/neo-security.xml file in the server configuration, or the cf_root/WEB-INF/cfusion/lib/neo-security.xml file in the J2EE configuration to the variable value. You can customize the patterns that ColdFusion replaces by modifying the regular expression in the CrossSiteScriptPatterns variable.
Locking server, application, and session variables When you set or update variables in the server, application, and session scopes, use the cflock tag with the scope attribute set to the following value: For server variables, specify "server" For application variables, specify "application" For session variables, specify "session" In some cases, you should also lock code that reads variables in these scopes. For information about locking scopes, see cflock on page 522.
Example
    <!--- This example shows how to use cflock to prevent race conditions during
    data updates to variables in Application, Server, and Session scopes. --->
    <h3>cfapplication Example</h3>
    <p>cfapplication defines scoping for a ColdFusion application and enables or
    disables application and/or session variable storage. This tag is placed in
    a special file called Application.cfm that automatically runs before any
    other CF page in a directory (or subdirectory) where the Application.cfm
    file appears.</p>

    <cfapplication name = "ETurtle"
    sessionTimeout = #CreateTimeSpan(0, 0, 0, 60)#
    sessionManagement = "Yes">

    <!--- Initialize session and application variables used by E-Turtleneck. --->
    <cfparam name="application.number" default="1">
    <cfparam name="session.color" default= "">
    <cfparam name="session.size" default="">

    <cfif IsDefined("session.numPurchased") AND
    IsNumeric(trim(session.cartTotal))>
    <!--- Use the application scope for the application variable to prevent race
    condition. This variable keeps track of total number of turtlenecks sold. --
    ->
       <cflock scope = "Application" timeout = "30" type = "Exclusive">
       <cfset application.number = application.number + session.numPurchased>
       </cflock>
    </cfif>

    <cfoutput>
    E-Turtleneck is proud to say that we have sold #application.number# turtlenecks
    to date.
    </cfoutput>
    <!--- End of Application.cfm --->

NAME |
| See Description
| For Application and Session variables: Required.
| For Client variables: Optional
Name of application. Up to 64 characters.

LOGINSTORAGE |
| Optional
Default value: "cookie" cookie: store login information in the Cookie scope. session: store login information in the Session scope.

CLIENTMANAGEMENT |
| Optional
Default value: "no" yes: enables client variables. no

CLIENTSTORAGE |
| Optional
Default value: "registry" How client variables are stored: datasource_name: in ODBC or native data source. You must create storage repository in the Administrator. registry: in the system registry. cookie: on client computer in a cookie. Scalable. If client disables cookies in the browser, client variables do not work.

SETCLIENTCOOKIES |
| Optional
Default value: "yes" yes: enables client cookies. no: ColdFusion does not automatically send CFID and CFTOKEN cookies to client browser; you must manually code CFID and CFTOKEN on the URL for every page that uses Session or Client variables.

SESSIONMANAGEMENT |
| Optional
Default value: "no" yes: enables session variables. no

SESSIONTIMEOUT |
| Optional
Default value: "Specified in Variables page of ColdFusion Administrator" Lifespan of session variables. CreateTimeSpan function and values in days, hours, minutes, and seconds, separated by commas.

APPLICATIONTIMEOUT |
| Optional
Default value: "Specified in Variables page of ColdFusion Administrator" Lifespan of application variables. CreateTimeSpan function and values in days, hours, minutes, and seconds, separated by commas.

SETDOMAINCOOKIES |
| Optional
Default value: "no" yes: uses domain cookies for CFID and CFTOKEN cookies and for all Client variables when using cookies for client variable storage. Required for applications running on clusters. no: uses host-specific cookies for CFID, CFTOKEN, and all client variable cookies.

SCRIPTPROTECT |
| Optional
Default value: "Determined by ColdFusion MX Administrator Enable Global Script Protection setting" Specifies whether to protect variables from cross-site scripting attacks none: do not protect variables all: protect Form, URL, CGI, and Cookie variables comma-delimited list of ColdFusion scopes: Protect variables in the specified scopes. For more information, see Usage.